smalltalk-tng
view experiments/assembly/jonesforth.S @ 321:c4a0718c2d3c
Sketch of dependencies
| author | Tony Garnock-Jones <tonygarnockjones@gmail.com> |
|---|---|
| date | Sat Oct 08 15:36:03 2011 -0400 (7 months ago) |
| parents | 608899826a12 |
| children |
line source
1 /* A sometimes minimal FORTH compiler and tutorial for Linux / i386 systems. -*- asm -*-
2 By Richard W.M. Jones <rich@annexia.org> http://annexia.org/forth
3 This is PUBLIC DOMAIN (see public domain release statement below).
4 $Id: jonesforth.S,v 1.19 2007/09/08 22:51:28 rich Exp $
6 gcc -m32 -nostdlib -static -Wl,-Ttext,0 -o jonesforth jonesforth.S
7 */
8 .set JONES_VERSION,19
9 /*
10 INTRODUCTION ----------------------------------------------------------------------
12 FORTH is one of those alien languages which most working programmers regard in the same
13 way as Haskell, LISP, and so on. Something so strange that they'd rather any thoughts
14 of it just go away so they can get on with writing this paying code. But that's wrong
15 and if you care at all about programming then you should at least understand all these
16 languages, even if you will never use them.
18 LISP is the ultimate high-level language, and features from LISP are being added every
19 decade to the more common languages. But FORTH is in some ways the ultimate in low level
20 programming. Out of the box it lacks features like dynamic memory management and even
21 strings. In fact, at its primitive level it lacks even basic concepts like IF-statements
22 and loops.
24 Why then would you want to learn FORTH? There are several very good reasons. First
25 and foremost, FORTH is minimal. You really can write a complete FORTH in, say, 2000
26 lines of code. I don't just mean a FORTH program, I mean a complete FORTH operating
27 system, environment and language. You could boot such a FORTH on a bare PC and it would
28 come up with a prompt where you could start doing useful work. The FORTH you have here
29 isn't minimal and uses a Linux process as its 'base PC' (both for the purposes of making
30 it a good tutorial). It's possible to completely understand the system. Who can say they
31 completely understand how Linux works, or gcc?
33 Secondly FORTH has a peculiar bootstrapping property. By that I mean that after writing
34 a little bit of assembly to talk to the hardware and implement a few primitives, all the
35 rest of the language and compiler is written in FORTH itself. Remember I said before
36 that FORTH lacked IF-statements and loops? Well of course it doesn't really because
37 such a lanuage would be useless, but my point was rather that IF-statements and loops are
38 written in FORTH itself.
40 Now of course this is common in other languages as well, and in those languages we call
41 them 'libraries'. For example in C, 'printf' is a library function written in C. But
42 in FORTH this goes way beyond mere libraries. Can you imagine writing C's 'if' in C?
43 And that brings me to my third reason: If you can write 'if' in FORTH, then why restrict
44 yourself to the usual if/while/for/switch constructs? You want a construct that iterates
45 over every other element in a list of numbers? You can add it to the language. What
46 about an operator which pulls in variables directly from a configuration file and makes
47 them available as FORTH variables? Or how about adding Makefile-like dependencies to
48 the language? No problem in FORTH. This concept isn't common in programming languages,
49 but it has a name (in fact two names): "macros" (by which I mean LISP-style macros, not
50 the lame C preprocessor) and "domain specific languages" (DSLs).
52 This tutorial isn't about learning FORTH as the language. I'll point you to some references
53 you should read if you're not familiar with using FORTH. This tutorial is about how to
54 write FORTH. In fact, until you understand how FORTH is written, you'll have only a very
55 superficial understanding of how to use it.
57 So if you're not familiar with FORTH or want to refresh your memory here are some online
58 references to read:
60 http://en.wikipedia.org/wiki/Forth_%28programming_language%29
62 http://galileo.phys.virginia.edu/classes/551.jvn.fall01/primer.htm
64 http://wiki.laptop.org/go/Forth_Lessons
66 Here is another "Why FORTH?" essay: http://www.jwdt.com/~paysan/why-forth.html
68 ACKNOWLEDGEMENTS ----------------------------------------------------------------------
70 This code draws heavily on the design of LINA FORTH (http://home.hccnet.nl/a.w.m.van.der.horst/lina.html)
71 by Albert van der Horst. Any similarities in the code are probably not accidental.
73 Also I used this document (http://ftp.funet.fi/pub/doc/IOCCC/1992/buzzard.2.design) which really
74 defies easy explanation.
76 PUBLIC DOMAIN ----------------------------------------------------------------------
78 I, the copyright holder of this work, hereby release it into the public domain. This applies worldwide.
80 In case this is not legally possible, I grant any entity the right to use this work for any purpose,
81 without any conditions, unless such conditions are required by law.
83 SETTING UP ----------------------------------------------------------------------
85 Let's get a few housekeeping things out of the way. Firstly because I need to draw lots of
86 ASCII-art diagrams to explain concepts, the best way to look at this is using a window which
87 uses a fixed width font and is at least this wide:
89 <------------------------------------------------------------------------------------------------------------------------>
91 Secondly make sure TABS are set to 8 characters. The following should be a vertical
92 line. If not, sort out your tabs.
94 |
95 |
96 |
98 Thirdly I assume that your screen is at least 50 characters high.
100 ASSEMBLING ----------------------------------------------------------------------
102 If you want to actually run this FORTH, rather than just read it, you will need Linux on an
103 i386. Linux because instead of programming directly to the hardware on a bare PC which I
104 could have done, I went for a simpler tutorial by assuming that the 'hardware' is a Linux
105 process with a few basic system calls (read, write and exit and that's about all). i386
106 is needed because I had to write the assembly for a processor, and i386 is by far the most
107 common. (Of course when I say 'i386', any 32- or 64-bit x86 processor will do. I'm compiling
108 this on a 64 bit AMD Opteron).
110 Again, to assemble this you will need gcc and gas (the GNU assembler). The commands to
111 assemble and run the code (save this file as 'jonesforth.S') are:
113 gcc -m32 -nostdlib -static -Wl,-Ttext,0 -o jonesforth jonesforth.S
114 ./jonesforth
116 You will see lots of 'Warning: unterminated string; newline inserted' messages from the
117 assembler. That's just because the GNU assembler doesn't have a good syntax for multi-line
118 strings (or rather it used to, but the developers removed it!) so I've abused the syntax
119 slightly to make things readable. Ignore these warnings.
121 If you want to run your own FORTH programs you can do:
123 ./jonesforth < myprog.f
125 If you want to load your own FORTH code and then continue reading user commands, you can do:
127 cat myfunctions.f - | ./jonesforth
129 ASSEMBLER ----------------------------------------------------------------------
131 (You can just skip to the next section -- you don't need to be able to read assembler to
132 follow this tutorial).
134 However if you do want to read the assembly code here are a few notes about gas (the GNU assembler):
136 (1) Register names are prefixed with '%', so %eax is the 32 bit i386 accumulator. The registers
137 available on i386 are: %eax, %ebx, %ecx, %edx, %esi, %edi, %ebp and %esp, and most of them
138 have special purposes.
140 (2) Add, mov, etc. take arguments in the form SRC,DEST. So mov %eax,%ecx moves %eax -> %ecx
142 (3) Constants are prefixed with '$', and you mustn't forget it! If you forget it then it
143 causes a read from memory instead, so:
144 mov $2,%eax moves number 2 into %eax
145 mov 2,%eax reads the 32 bit word from address 2 into %eax (ie. most likely a mistake)
147 (4) gas has a funky syntax for local labels, where '1f' (etc.) means label '1:' "forwards"
148 and '1b' (etc.) means label '1:' "backwards".
150 (5) 'ja' is "jump if above", 'jb' for "jump if below", 'je' "jump if equal" etc.
152 (6) gas has a reasonably nice .macro syntax, and I use them a lot to make the code shorter and
153 less repetitive.
155 For more help reading the assembler, do "info gas" at the Linux prompt.
157 Now the tutorial starts in earnest.
159 THE DICTIONARY ----------------------------------------------------------------------
161 In FORTH as you will know, functions are called "words", and just as in other languages they
162 have a name and a definition. Here are two FORTH words:
164 : DOUBLE DUP + ; \ name is "DOUBLE", definition is "DUP +"
165 : QUADRUPLE DOUBLE DOUBLE ; \ name is "QUADRUPLE", definition is "DOUBLE DOUBLE"
167 Words, both built-in ones and ones which the programmer defines later, are stored in a dictionary
168 which is just a linked list of dictionary entries.
170 <--- DICTIONARY ENTRY (HEADER) ----------------------->
171 +------------------------+--------+---------- - - - - +----------- - - - -
172 | LINK POINTER | LENGTH/| NAME | DEFINITION
173 | | FLAGS | |
174 +--- (4 bytes) ----------+- byte -+- n bytes - - - - +----------- - - - -
176 I'll come to the definition of the word later. For now just look at the header. The first
177 4 bytes are the link pointer. This points back to the previous word in the dictionary, or, for
178 the first word in the dictionary it is just a NULL pointer. Then comes a length/flags byte.
179 The length of the word can be up to 31 characters (5 bits used) and the top three bits are used
180 for various flags which I'll come to later. This is followed by the name itself, and in this
181 implementation the name is rounded up to a multiple of 4 bytes by padding it with zero bytes.
182 That's just to ensure that the definition starts on a 32 bit boundary.
184 A FORTH variable called LATEST contains a pointer to the most recently defined word, in
185 other words, the head of this linked list.
187 DOUBLE and QUADRUPLE might look like this:
189 pointer to previous word
190 ^
191 |
192 +--|------+---+---+---+---+---+---+---+---+------------- - - - -
193 | LINK | 6 | D | O | U | B | L | E | 0 | (definition ...)
194 +---------+---+---+---+---+---+---+---+---+------------- - - - -
195 ^ len padding
196 |
197 +--|------+---+---+---+---+---+---+---+---+---+---+---+---+------------- - - - -
198 | LINK | 9 | Q | U | A | D | R | U | P | L | E | 0 | 0 | (definition ...)
199 +---------+---+---+---+---+---+---+---+---+---+---+---+---+------------- - - - -
200 ^ len padding
201 |
202 |
203 LATEST
205 You shoud be able to see from this how you might implement functions to find a word in
206 the dictionary (just walk along the dictionary entries starting at LATEST and matching
207 the names until you either find a match or hit the NULL pointer at the end of the dictionary);
208 and add a word to the dictionary (create a new definition, set its LINK to LATEST, and set
209 LATEST to point to the new word). We'll see precisely these functions implemented in
210 assembly code later on.
212 One interesting consequence of using a linked list is that you can redefine words, and
213 a newer definition of a word overrides an older one. This is an important concept in
214 FORTH because it means that any word (even "built-in" or "standard" words) can be
215 overridden with a new definition, either to enhance it, to make it faster or even to
216 disable it. However because of the way that FORTH words get compiled, which you'll
217 understand below, words defined using the old definition of a word continue to use
218 the old definition. Only words defined after the new definition use the new definition.
220 DIRECT THREADED CODE ----------------------------------------------------------------------
222 Now we'll get to the really crucial bit in understanding FORTH, so go and get a cup of tea
223 or coffee and settle down. It's fair to say that if you don't understand this section, then you
224 won't "get" how FORTH works, and that would be a failure on my part for not explaining it well.
225 So if after reading this section a few times you don't understand it, please email me
226 (rich@annexia.org).
228 Let's talk first about what "threaded code" means. Imagine a peculiar version of C where
229 you are only allowed to call functions without arguments. (Don't worry for now that such a
230 language would be completely useless!) So in our peculiar C, code would look like this:
232 f ()
233 {
234 a ();
235 b ();
236 c ();
237 }
239 and so on. How would a function, say 'f' above, be compiled by a standard C compiler?
240 Probably into assembly code like this. On the right hand side I've written the actual
241 i386 machine code.
243 f:
244 CALL a E8 08 00 00 00
245 CALL b E8 1C 00 00 00
246 CALL c E8 2C 00 00 00
247 ; ignore the return from the function for now
249 "E8" is the x86 machine code to "CALL" a function. In the first 20 years of computing
250 memory was hideously expensive and we might have worried about the wasted space being used
251 by the repeated "E8" bytes. We can save 20% in code size (and therefore, in expensive memory)
252 by compressing this into just:
254 08 00 00 00 Just the function addresses, without
255 1C 00 00 00 the CALL prefix.
256 2C 00 00 00
258 [Historical note: If the execution model that FORTH uses looks strange from the following
259 paragraphs, then it was motivated entirely by the need to save memory on early computers.
260 This code compression isn't so important now when our machines have more memory in their L1
261 caches than those early computers had in total, but the execution model still has some
262 useful properties].
264 Of course this code won't run directly any more. Instead we need to write an interpreter
265 which takes each pair of bytes and calls it.
267 On an i386 machine it turns out that we can write this interpreter rather easily, in just
268 two assembly instructions which turn into just 3 bytes of machine code. Let's store the
269 pointer to the next word to execute in the %esi register:
271 08 00 00 00 <- We're executing this one now. %esi is the _next_ one to execute.
272 %esi -> 1C 00 00 00
273 2C 00 00 00
275 The all-important i386 instruction is called LODSL (or in Intel manuals, LODSW). It does
276 two things. Firstly it reads the memory at %esi into the accumulator (%eax). Secondly it
277 increments %esi by 4 bytes. So after LODSL, the situation now looks like this:
279 08 00 00 00 <- We're still executing this one
280 1C 00 00 00 <- %eax now contains this address (0x0000001C)
281 %esi -> 2C 00 00 00
283 Now we just need to jump to the address in %eax. This is again just a single x86 instruction
284 written JMP *(%eax). And after doing the jump, the situation looks like:
286 08 00 00 00
287 1C 00 00 00 <- Now we're executing this subroutine.
288 %esi -> 2C 00 00 00
290 To make this work, each subroutine is followed by the two instructions 'LODSL; JMP *(%eax)'
291 which literally make the jump to the next subroutine.
293 And that brings us to our first piece of actual code! Well, it's a macro.
294 */
296 /* NEXT macro. */
297 .macro NEXT
298 lodsl
299 jmp *(%eax)
300 .endm
302 /* The macro is called NEXT. That's a FORTH-ism. It expands to those two instructions.
304 Every FORTH primitive that we write has to be ended by NEXT. Think of it kind of like
305 a return.
307 The above describes what is known as direct threaded code.
309 To sum up: We compress our function calls down to a list of addresses and use a somewhat
310 magical macro to act as a "jump to next function in the list". We also use one register (%esi)
311 to act as a kind of instruction pointer, pointing to the next function in the list.
313 I'll just give you a hint of what is to come by saying that a FORTH definition such as:
315 : QUADRUPLE DOUBLE DOUBLE ;
317 actually compiles (almost, not precisely but we'll see why in a moment) to a list of
318 function addresses for DOUBLE, DOUBLE and a special function called EXIT to finish off.
320 At this point, REALLY EAGLE-EYED ASSEMBLY EXPERTS are saying "JONES, YOU'VE MADE A MISTAKE!".
322 I lied about JMP *(%eax).
324 INDIRECT THREADED CODE ----------------------------------------------------------------------
326 It turns out that direct threaded code is interesting but only if you want to just execute
327 a list of functions written in assembly language. So QUADRUPLE would work only if DOUBLE
328 was an assembly language function. In the direct threaded code, QUADRUPLE would look like:
330 +------------------+
331 | addr of DOUBLE --------------------> (assembly code to do the double)
332 +------------------+ NEXT
333 %esi -> | addr of DOUBLE |
334 +------------------+
336 We can add an extra indirection to allow us to run both words written in assembly language
337 (primitives written for speed) and words written in FORTH themselves as lists of addresses.
339 The extra indirection is the reason for the brackets in JMP *(%eax).
341 Let's have a look at how QUADRUPLE and DOUBLE really look in FORTH:
343 : QUADRUPLE DOUBLE DOUBLE ;
345 +------------------+
346 | codeword | : DOUBLE DUP + ;
347 +------------------+
348 | addr of DOUBLE ---------------> +------------------+
349 +------------------+ | codeword |
350 | addr of DOUBLE | +------------------+
351 +------------------+ | addr of DUP --------------> +------------------+
352 | addr of EXIT | +------------------+ | codeword -------+
353 +------------------+ %esi -> | addr of + --------+ +------------------+ |
354 +------------------+ | | assembly to <-----+
355 | addr of EXIT | | | implement DUP |
356 +------------------+ | | .. |
357 | | .. |
358 | | NEXT |
359 | +------------------+
360 |
361 +-----> +------------------+
362 | codeword -------+
363 +------------------+ |
364 | assembly to <------+
365 | implement + |
366 | .. |
367 | .. |
368 | NEXT |
369 +------------------+
371 This is the part where you may need an extra cup of tea/coffee/favourite caffeinated
372 beverage. What has changed is that I've added an extra pointer to the beginning of
373 the definitions. In FORTH this is sometimes called the "codeword". The codeword is
374 a pointer to the interpreter to run the function. For primitives written in
375 assembly language, the "interpreter" just points to the actual assembly code itself.
376 They don't need interpreting, they just run.
378 In words written in FORTH (like QUADRUPLE and DOUBLE), the codeword points to an interpreter
379 function.
381 I'll show you the interpreter function shortly, but let's recall our indirect
382 JMP *(%eax) with the "extra" brackets. Take the case where we're executing DOUBLE
383 as shown, and DUP has been called. Note that %esi is pointing to the address of +
385 The assembly code for DUP eventually does a NEXT. That:
387 (1) reads the address of + into %eax %eax points to the codeword of +
388 (2) increments %esi by 4
389 (3) jumps to the indirect %eax jumps to the address in the codeword of +,
390 ie. the assembly code to implement +
392 +------------------+
393 | codeword |
394 +------------------+
395 | addr of DOUBLE ---------------> +------------------+
396 +------------------+ | codeword |
397 | addr of DOUBLE | +------------------+
398 +------------------+ | addr of DUP --------------> +------------------+
399 | addr of EXIT | +------------------+ | codeword -------+
400 +------------------+ | addr of + --------+ +------------------+ |
401 +------------------+ | | assembly to <-----+
402 %esi -> | addr of EXIT | | | implement DUP |
403 +------------------+ | | .. |
404 | | .. |
405 | | NEXT |
406 | +------------------+
407 |
408 +-----> +------------------+
409 | codeword -------+
410 +------------------+ |
411 now we're | assembly to <------+
412 executing | implement + |
413 this | .. |
414 function | .. |
415 | NEXT |
416 +------------------+
418 So I hope that I've convinced you that NEXT does roughly what you'd expect. This is
419 indirect threaded code.
421 I've glossed over four things. I wonder if you can guess without reading on what they are?
423 .
424 .
425 .
427 My list of four things are: (1) What does "EXIT" do? (2) which is related to (1) is how do
428 you call into a function, ie. how does %esi start off pointing at part of QUADRUPLE, but
429 then point at part of DOUBLE. (3) What goes in the codeword for the words which are written
430 in FORTH? (4) How do you compile a function which does anything except call other functions
431 ie. a function which contains a number like : DOUBLE 2 * ; ?
433 THE INTERPRETER AND RETURN STACK ------------------------------------------------------------
435 Going at these in no particular order, let's talk about issues (3) and (2), the interpreter
436 and the return stack.
438 Words which are defined in FORTH need a codeword which points to a little bit of code to
439 give them a "helping hand" in life. They don't need much, but they do need what is known
440 as an "interpreter", although it doesn't really "interpret" in the same way that, say,
441 Java bytecode used to be interpreted (ie. slowly). This interpreter just sets up a few
442 machine registers so that the word can then execute at full speed using the indirect
443 threaded model above.
445 One of the things that needs to happen when QUADRUPLE calls DOUBLE is that we save the old
446 %esi ("instruction pointer") and create a new one pointing to the first word in DOUBLE.
447 Because we will need to restore the old %esi at the end of DOUBLE (this is, after all, like
448 a function call), we will need a stack to store these "return addresses" (old values of %esi).
450 As you will have read, when reading the background documentation, FORTH has two stacks,
451 an ordinary stack for parameters, and a return stack which is a bit more mysterious. But
452 our return stack is just the stack I talked about in the previous paragraph, used to save
453 %esi when calling from a FORTH word into another FORTH word.
455 In this FORTH, we are using the normal stack pointer (%esp) for the parameter stack.
456 We will use the i386's "other" stack pointer (%ebp, usually called the "frame pointer")
457 for our return stack.
459 I've got two macros which just wrap up the details of using %ebp for the return stack.
460 You use them as for example "PUSHRSP %eax" (push %eax on the return stack) or "POPRSP %ebx"
461 (pop top of return stack into %ebx).
462 */
464 /* Macros to deal with the return stack. */
465 .macro PUSHRSP reg
466 lea -4(%ebp),%ebp // push reg on to return stack
467 movl \reg,(%ebp)
468 .endm
470 .macro POPRSP reg
471 mov (%ebp),\reg // pop top of return stack to reg
472 lea 4(%ebp),%ebp
473 .endm
475 /*
476 And with that we can now talk about the interpreter.
478 In FORTH the interpreter function is often called DOCOL (I think it means "DO COLON" because
479 all FORTH definitions start with a colon, as in : DOUBLE DUP + ;
481 The "interpreter" (it's not really "interpreting") just needs to push the old %esi on the
482 stack and set %esi to the first word in the definition. Remember that we jumped to the
483 function using JMP *(%eax)? Well a consequence of that is that conveniently %eax contains
484 the address of this codeword, so just by adding 4 to it we get the address of the first
485 data word. Finally after setting up %esi, it just does NEXT which causes that first word
486 to run.
487 */
489 /* DOCOL - the interpreter! */
490 .text
491 .align 4
492 DOCOL:
493 PUSHRSP %esi // push %esi on to the return stack
494 addl $4,%eax // %eax points to codeword, so make
495 movl %eax,%esi // %esi point to first data word
496 NEXT
498 /*
499 Just to make this absolutely clear, let's see how DOCOL works when jumping from QUADRUPLE
500 into DOUBLE:
502 QUADRUPLE:
503 +------------------+
504 | codeword |
505 +------------------+ DOUBLE:
506 | addr of DOUBLE ---------------> +------------------+
507 +------------------+ %eax -> | addr of DOCOL |
508 %esi -> | addr of DOUBLE | +------------------+
509 +------------------+ | addr of DUP |
510 | addr of EXIT | +------------------+
511 +------------------+ | etc. |
513 First, the call to DOUBLE calls DOCOL (the codeword of DOUBLE). DOCOL does this: It
514 pushes the old %esi on the return stack. %eax points to the codeword of DOUBLE, so we
515 just add 4 on to it to get our new %esi:
517 QUADRUPLE:
518 +------------------+
519 | codeword |
520 +------------------+ DOUBLE:
521 | addr of DOUBLE ---------------> +------------------+
522 top of return +------------------+ %eax -> | addr of DOCOL |
523 stack points -> | addr of DOUBLE | + 4 = +------------------+
524 +------------------+ %esi -> | addr of DUP |
525 | addr of EXIT | +------------------+
526 +------------------+ | etc. |
528 Then we do NEXT, and because of the magic of threaded code that increments %esi again
529 and calls DUP.
531 Well, it seems to work.
533 One minor point here. Because DOCOL is the first bit of assembly actually to be defined
534 in this file (the others were just macros), and because I usually compile this code with the
535 text segment starting at address 0, DOCOL has address 0. So if you are disassembling the
536 code and see a word with a codeword of 0, you will immediately know that the word is
537 written in FORTH (it's not an assembler primitive) and so uses DOCOL as the interpreter.
539 STARTING UP ----------------------------------------------------------------------
541 Now let's get down to nuts and bolts. When we start the program we need to set up
542 a few things like the return stack. But as soon as we can, we want to jump into FORTH
543 code (albeit much of the "early" FORTH code will still need to be written as
544 assembly language primitives).
546 This is what the set up code does. Does a tiny bit of house-keeping, sets up the
547 separate return stack (NB: Linux gives us the ordinary parameter stack already), then
548 immediately jumps to a FORTH word called COLD. COLD stands for cold-start. In ISO
549 FORTH (but not in this FORTH), COLD can be called at any time to completely reset
550 the state of FORTH, and there is another word called WARM which does a partial reset.
551 */
553 /* ELF entry point. */
554 .text
555 .globl _start
556 _start:
557 cld
558 mov %esp,var_S0 // Store the initial data stack pointer.
559 mov $return_stack,%ebp // Initialise the return stack.
561 mov $cold_start,%esi // Initialise interpreter.
562 NEXT // Run interpreter!
564 .section .rodata
565 cold_start: // High-level code without a codeword.
566 .int COLD
568 /*
569 We also allocate some space for the return stack and some space to store user
570 definitions. These are static memory allocations using fixed-size buffers, but it
571 wouldn't be a great deal of work to make them dynamic.
572 */
574 .bss
575 /* FORTH return stack. */
576 #define RETURN_STACK_SIZE 8192
577 .align 4096
578 .space RETURN_STACK_SIZE
579 return_stack: // Initial top of return stack.
581 /* Space for user-defined words. */
582 #define USER_DEFS_SIZE 16384
583 .align 4096
584 user_defs_start:
585 .space USER_DEFS_SIZE
587 /*
588 BUILT-IN WORDS ----------------------------------------------------------------------
590 Remember our dictionary entries (headers). Let's bring those together with the codeword
591 and data words to see how : DOUBLE DUP + ; really looks in memory.
593 pointer to previous word
594 ^
595 |
596 +--|------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
597 | LINK | 6 | D | O | U | B | L | E | 0 | DOCOL | DUP | + | EXIT |
598 +---------+---+---+---+---+---+---+---+---+------------+--|---------+------------+------------+
599 ^ len pad codeword |
600 | V
601 LINK in next word points to codeword of DUP
603 Initially we can't just write ": DOUBLE DUP + ;" (ie. that literal string) here because we
604 don't yet have anything to read the string, break it up at spaces, parse each word, etc. etc.
605 So instead we will have to define built-in words using the GNU assembler data constructors
606 (like .int, .byte, .string, .ascii and so on -- look them up in the gas info page if you are
607 unsure of them).
609 The long way would be:
610 .int <link to previous word>
611 .byte 6 // len
612 .ascii "DOUBLE" // string
613 .byte 0 // padding
614 DOUBLE: .int DOCOL // codeword
615 .int DUP // pointer to codeword of DUP
616 .int PLUS // pointer to codeword of +
617 .int EXIT // pointer to codeword of EXIT
619 That's going to get quite tedious rather quickly, so here I define an assembler macro
620 so that I can just write:
622 defword "DOUBLE",6,,DOUBLE
623 .int DUP,PLUS,EXIT
625 and I'll get exactly the same effect.
627 Don't worry too much about the exact implementation details of this macro - it's complicated!
628 */
630 /* Flags - these are discussed later. */
631 #define F_IMMED 0x80
632 #define F_HIDDEN 0x20
634 // Store the chain of links.
635 .set link,0
637 .macro defword name, namelen, flags=0, label
638 .section .rodata
639 .align 4
640 .globl name_\label
641 name_\label :
642 .int link // link
643 .set link,name_\label
644 .byte \flags+\namelen // flags + length byte
645 .ascii "\name" // the name
646 .align 4
647 .globl \label
648 \label :
649 .int DOCOL // codeword - the interpreter
650 // list of word pointers follow
651 .endm
653 /*
654 Similarly I want a way to write words written in assembly language. There will quite a few
655 of these to start with because, well, everything has to start in assembly before there's
656 enough "infrastructure" to be able to start writing FORTH words, but also I want to define
657 some common FORTH words in assembly language for speed, even though I could write them in FORTH.
659 This is what DUP looks like in memory:
661 pointer to previous word
662 ^
663 |
664 +--|------+---+---+---+---+------------+
665 | LINK | 3 | D | U | P | code_DUP ---------------------> points to the assembly
666 +---------+---+---+---+---+------------+ code used to write DUP,
667 ^ len codeword which ends with NEXT.
668 |
669 LINK in next word
671 Again, for brevity in writing the header I'm going to write an assembler macro called defcode.
672 */
674 .macro defcode name, namelen, flags=0, label
675 .section .rodata
676 .align 4
677 .globl name_\label
678 name_\label :
679 .int link // link
680 .set link,name_\label
681 .byte \flags+\namelen // flags + length byte
682 .ascii "\name" // the name
683 .align 4
684 .globl \label
685 \label :
686 .int code_\label // codeword
687 .text
688 .align 4
689 .globl code_\label
690 code_\label : // assembler code follows
691 .endm
693 /*
694 Now some easy FORTH primitives. These are written in assembly for speed. If you understand
695 i386 assembly language then it is worth reading these. However if you don't understand assembly
696 you can skip the details.
697 */
699 defcode "DUP",3,,DUP
700 pop %eax // duplicate top of stack
701 push %eax
702 push %eax
703 NEXT
705 defcode "DROP",4,,DROP
706 pop %eax // drop top of stack
707 NEXT
709 defcode "SWAP",4,,SWAP
710 pop %eax // swap top of stack
711 pop %ebx
712 push %eax
713 push %ebx
714 NEXT
716 defcode "OVER",4,,OVER
717 mov 4(%esp),%eax // get the second element of stack
718 push %eax // and push it on top
719 NEXT
721 defcode "ROT",3,,ROT
722 pop %eax
723 pop %ebx
724 pop %ecx
725 push %eax
726 push %ecx
727 push %ebx
728 NEXT
730 defcode "-ROT",4,,NROT
731 pop %eax
732 pop %ebx
733 pop %ecx
734 push %ebx
735 push %eax
736 push %ecx
737 NEXT
739 defcode "1+",2,,INCR
740 incl (%esp) // increment top of stack
741 NEXT
743 defcode "1-",2,,DECR
744 decl (%esp) // decrement top of stack
745 NEXT
747 defcode "4+",2,,INCR4
748 addl $4,(%esp) // add 4 to top of stack
749 NEXT
751 defcode "4-",2,,DECR4
752 subl $4,(%esp) // subtract 4 from top of stack
753 NEXT
755 defcode "+",1,,ADD
756 pop %eax // get top of stack
757 addl %eax,(%esp) // and add it to next word on stack
758 NEXT
760 defcode "-",1,,SUB
761 pop %eax // get top of stack
762 subl %eax,(%esp) // and subtract it from next word on stack
763 NEXT
765 defcode "*",1,,MUL
766 pop %eax
767 pop %ebx
768 imull %ebx,%eax
769 push %eax // ignore overflow
770 NEXT
772 defcode "/",1,,DIV
773 xor %edx,%edx
774 pop %ebx
775 pop %eax
776 idivl %ebx
777 push %eax // push quotient
778 NEXT
780 defcode "MOD",3,,MOD
781 xor %edx,%edx
782 pop %ebx
783 pop %eax
784 idivl %ebx
785 push %edx // push remainder
786 NEXT
788 defcode "=",1,,EQU // top two words are equal?
789 pop %eax
790 pop %ebx
791 cmp %ebx,%eax
792 je 1f
793 pushl $0
794 NEXT
795 1: pushl $1
796 NEXT
798 defcode "<>",2,,NEQU // top two words are not equal?
799 pop %eax
800 pop %ebx
801 cmp %ebx,%eax
802 je 1f
803 pushl $1
804 NEXT
805 1: pushl $0
806 NEXT
808 defcode ">",1,,GT // greater-than
809 pop %eax
810 pop %ebx
811 cmp %ebx,%eax
812 jl 1f
813 pushl $0
814 NEXT
815 1: pushl $1
816 NEXT
818 defcode "0=",2,,ZEQU // top of stack equals 0?
819 pop %eax
820 test %eax,%eax
821 jz 1f
822 pushl $0
823 NEXT
824 1: pushl $1
825 NEXT
827 defcode "AND",3,,AND
828 pop %eax
829 andl %eax,(%esp)
830 NEXT
832 defcode "OR",2,,OR
833 pop %eax
834 orl %eax,(%esp)
835 NEXT
837 defcode "INVERT",6,,INVERT // this is the FORTH "NOT" function
838 notl (%esp)
839 NEXT
841 /*
842 RETURNING FROM FORTH WORDS ----------------------------------------------------------------------
844 Time to talk about what happens when we EXIT a function. In this diagram QUADRUPLE has called
845 DOUBLE, and DOUBLE is about to exit (look at where %esi is pointing):
847 QUADRUPLE
848 +------------------+
849 | codeword |
850 +------------------+ DOUBLE
851 | addr of DOUBLE ---------------> +------------------+
852 +------------------+ | codeword |
853 | addr of DOUBLE | +------------------+
854 +------------------+ | addr of DUP |
855 | addr of EXIT | +------------------+
856 +------------------+ | addr of + |
857 +------------------+
858 %esi -> | addr of EXIT |
859 +------------------+
861 What happens when the + function does NEXT? Well, the following code is executed.
862 */
864 defcode "EXIT",4,,EXIT
865 POPRSP %esi // pop return stack into %esi
866 NEXT
868 /*
869 EXIT gets the old %esi which we saved from before on the return stack, and puts it in %esi.
870 So after this (but just before NEXT) we get:
872 QUADRUPLE
873 +------------------+
874 | codeword |
875 +------------------+ DOUBLE
876 | addr of DOUBLE ---------------> +------------------+
877 +------------------+ | codeword |
878 %esi -> | addr of DOUBLE | +------------------+
879 +------------------+ | addr of DUP |
880 | addr of EXIT | +------------------+
881 +------------------+ | addr of + |
882 +------------------+
883 | addr of EXIT |
884 +------------------+
886 And NEXT just completes the job by, well in this case just by calling DOUBLE again :-)
888 LITERALS ----------------------------------------------------------------------
890 The final point I "glossed over" before was how to deal with functions that do anything
891 apart from calling other functions. For example, suppose that DOUBLE was defined like this:
893 : DOUBLE 2 * ;
895 It does the same thing, but how do we compile it since it contains the literal 2? One way
896 would be to have a function called "2" (which you'd have to write in assembler), but you'd need
897 a function for every single literal that you wanted to use.
899 FORTH solves this by compiling the function using a special word called LIT:
901 +---------------------------+-------+-------+-------+-------+-------+
902 | (usual header of DOUBLE) | DOCOL | LIT | 2 | * | EXIT |
903 +---------------------------+-------+-------+-------+-------+-------+
905 LIT is executed in the normal way, but what it does next is definitely not normal. It
906 looks at %esi (which now points to the literal 2), grabs it, pushes it on the stack, then
907 manipulates %esi in order to skip the literal as if it had never been there.
909 What's neat is that the whole grab/manipulate can be done using a single byte single
910 i386 instruction, our old friend LODSL. Rather than me drawing more ASCII-art diagrams,
911 see if you can find out how LIT works:
912 */
914 defcode "LIT",3,,LIT
915 // %esi points to the next command, but in this case it points to the next
916 // literal 32 bit integer. Get that literal into %eax and increment %esi.
917 // On x86, it's a convenient single byte instruction! (cf. NEXT macro)
918 lodsl
919 push %eax // push the literal number on to stack
920 NEXT
922 /*
923 MEMORY ----------------------------------------------------------------------
925 As important point about FORTH is that it gives you direct access to the lowest levels
926 of the machine. Manipulating memory directly is done frequently in FORTH, and these are
927 the primitive words for doing it.
928 */
930 defcode "!",1,,STORE
931 pop %ebx // address to store at
932 pop %eax // data to store there
933 mov %eax,(%ebx) // store it
934 NEXT
936 defcode "@",1,,FETCH
937 pop %ebx // address to fetch
938 mov (%ebx),%eax // fetch it
939 push %eax // push value onto stack
940 NEXT
942 defcode "+!",2,,ADDSTORE
943 pop %ebx // address
944 pop %eax // the amount to add
945 addl %eax,(%ebx) // add it
946 NEXT
948 defcode "-!",2,,SUBSTORE
949 pop %ebx // address
950 pop %eax // the amount to subtract
951 subl %eax,(%ebx) // add it
952 NEXT
954 /* ! and @ (STORE and FETCH) store 32-bit words. It's also useful to be able to read and write bytes.
955 * I don't know whether FORTH has these words, so I invented my own, called !b and @b.
956 * Byte-oriented operations only work on architectures which permit them (i386 is one of those).
957 * UPDATE: writing a byte to the dictionary pointer is called C, in FORTH.
958 */
959 defcode "!b",2,,STOREBYTE
960 pop %ebx // address to store at
961 pop %eax // data to store there
962 movb %al,(%ebx) // store it
963 NEXT
965 defcode "@b",2,,FETCHBYTE
966 pop %ebx // address to fetch
967 xor %eax,%eax
968 movb (%ebx),%al // fetch it
969 push %eax // push value onto stack
970 NEXT
972 /*
973 BUILT-IN VARIABLES ----------------------------------------------------------------------
975 These are some built-in variables and related standard FORTH words. Of these, the only one that we
976 have discussed so far was LATEST, which points to the last (most recently defined) word in the
977 FORTH dictionary. LATEST is also a FORTH word which pushes the address of LATEST (the variable)
978 on to the stack, so you can read or write it using @ and ! operators. For example, to print
979 the current value of LATEST (and this can apply to any FORTH variable) you would do:
981 LATEST @ . CR
983 To make defining variables shorter, I'm using a macro called defvar, similar to defword and
984 defcode above. (In fact the defvar macro uses defcode to do the dictionary header).
985 */
987 .macro defvar name, namelen, flags=0, label, initial=0
988 defcode \name,\namelen,\flags,\label
989 push $var_\name
990 NEXT
991 .data
992 .align 4
993 var_\name :
994 .int \initial
995 .endm
997 /*
998 The built-in variables are:
1000 STATE Is the interpreter executing code (0) or compiling a word (non-zero)?
1001 LATEST Points to the latest (most recently defined) word in the dictionary.
1002 HERE Points to the next free byte of memory. When compiling, compiled words go here.
1003 _X These are three scratch variables, used by some standard dictionary words.
1004 _Y
1005 _Z
1006 S0 Stores the address of the top of the parameter stack.
1007 R0 Stores the address of the top of the return stack.
1008 VERSION Is the current version of this FORTH.
1010 */
1011 defvar "STATE",5,,STATE
1012 defvar "HERE",4,,HERE,user_defs_start
1013 defvar "LATEST",6,,LATEST,name_SYSEXIT // SYSEXIT must be last in built-in dictionary
1014 defvar "_X",2,,TX
1015 defvar "_Y",2,,TY
1016 defvar "_Z",2,,TZ
1017 defvar "S0",2,,SZ
1018 defvar "R0",2,,RZ,return_stack
1019 defvar "VERSION",7,,VERSION,JONES_VERSION
1021 /*
1022 RETURN STACK ----------------------------------------------------------------------
1024 These words allow you to access the return stack. Recall that the register %ebp always points to
1025 the top of the return stack.
1026 */
1028 defcode ">R",2,,TOR
1029 pop %eax // pop parameter stack into %eax
1030 PUSHRSP %eax // push it on to the return stack
1031 NEXT
1033 defcode "R>",2,,FROMR
1034 POPRSP %eax // pop return stack on to %eax
1035 push %eax // and push on to parameter stack
1036 NEXT
1038 defcode "RSP@",4,,RSPFETCH
1039 push %ebp
1040 NEXT
1042 defcode "RSP!",4,,RSPSTORE
1043 pop %ebp
1044 NEXT
1046 defcode "RDROP",5,,RDROP
1047 lea 4(%ebp),%ebp // pop return stack and throw away
1048 NEXT
1050 /*
1051 PARAMETER (DATA) STACK ----------------------------------------------------------------------
1053 These functions allow you to manipulate the parameter stack. Recall that Linux sets up the parameter
1054 stack for us, and it is accessed through %esp.
1055 */
1057 defcode "DSP@",4,,DSPFETCH
1058 mov %esp,%eax
1059 push %eax
1060 NEXT
1062 defcode "DSP!",4,,DSPSTORE
1063 pop %esp
1064 NEXT
1066 /*
1067 INPUT AND OUTPUT ----------------------------------------------------------------------
1069 These are our first really meaty/complicated FORTH primitives. I have chosen to write them in
1070 assembler, but surprisingly in "real" FORTH implementations these are often written in terms
1071 of more fundamental FORTH primitives. I chose to avoid that because I think that just obscures
1072 the implementation. After all, you may not understand assembler but you can just think of it
1073 as an opaque block of code that does what it says.
1075 Let's discuss input first.
1077 The FORTH word KEY reads the next byte from stdin (and pushes it on the parameter stack).
1078 So if KEY is called and someone hits the space key, then the number 32 (ASCII code of space)
1079 is pushed on the stack.
1081 In FORTH there is no distinction between reading code and reading input. We might be reading
1082 and compiling code, we might be reading words to execute, we might be asking for the user
1083 to type their name -- ultimately it all comes in through KEY.
1085 The implementation of KEY uses an input buffer of a certain size (defined at the end of the
1086 program). It calls the Linux read(2) system call to fill this buffer and tracks its position
1087 in the buffer using a couple of variables, and if it runs out of input buffer then it refills
1088 it automatically. The other thing that KEY does is if it detects that stdin has closed, it
1089 exits the program, which is why when you hit ^D the FORTH system cleanly exits.
1090 */
1092 #include <asm-i386/unistd.h>
1094 defcode "KEY",3,,KEY
1095 call _KEY
1096 push %eax // push return value on stack
1097 NEXT
1098 _KEY:
1099 mov (currkey),%ebx
1100 cmp (bufftop),%ebx
1101 jge 1f
1102 xor %eax,%eax
1103 mov (%ebx),%al
1104 inc %ebx
1105 mov %ebx,(currkey)
1106 ret
1108 1: // out of input; use read(2) to fetch more input from stdin
1109 xor %ebx,%ebx // 1st param: stdin
1110 mov $buffer,%ecx // 2nd param: buffer
1111 mov %ecx,currkey
1112 mov $buffend-buffer,%edx // 3rd param: max length
1113 mov $__NR_read,%eax // syscall: read
1114 int $0x80
1115 test %eax,%eax // If %eax <= 0, then exit.
1116 jbe 2f
1117 addl %eax,%ecx // buffer+%eax = bufftop
1118 mov %ecx,bufftop
1119 jmp _KEY
1121 2: // error or out of input: exit
1122 xor %ebx,%ebx
1123 mov $__NR_exit,%eax // syscall: exit
1124 int $0x80
1126 /*
1127 By contrast, output is much simpler. The FORTH word EMIT writes out a single byte to stdout.
1128 This implementation just uses the write system call. No attempt is made to buffer output, but
1129 it would be a good exercise to add it.
1130 */
1132 defcode "EMIT",4,,EMIT
1133 pop %eax
1134 call _EMIT
1135 NEXT
1136 _EMIT:
1137 mov $1,%ebx // 1st param: stdout
1139 // write needs the address of the byte to write
1140 mov %al,(2f)
1141 mov $2f,%ecx // 2nd param: address
1143 mov $1,%edx // 3rd param: nbytes = 1
1145 mov $__NR_write,%eax // write syscall
1146 int $0x80
1147 ret
1149 .bss
1150 2: .space 1 // scratch used by EMIT
1152 /*
1153 Back to input, WORD is a FORTH word which reads the next full word of input.
1155 What it does in detail is that it first skips any blanks (spaces, tabs, newlines and so on).
1156 Then it calls KEY to read characters into an internal buffer until it hits a blank. Then it
1157 calculates the length of the word it read and returns the address and the length as
1158 two words on the stack (with address at the top).
1160 Notice that WORD has a single internal buffer which it overwrites each time (rather like
1161 a static C string). Also notice that WORD's internal buffer is just 32 bytes long and
1162 there is NO checking for overflow. 31 bytes happens to be the maximum length of a
1163 FORTH word that we support, and that is what WORD is used for: to read FORTH words when
1164 we are compiling and executing code. The returned strings are not NUL-terminated, so
1165 in some crazy-world you could define FORTH words containing ASCII NULs, although why
1166 you'd want to is a bit beyond me.
1168 WORD is not suitable for just reading strings (eg. user input) because of all the above
1169 peculiarities and limitations.
1171 Note that when executing, you'll see:
1172 WORD FOO
1173 which puts "FOO" and length 3 on the stack, but when compiling:
1174 : BAR WORD FOO ;
1175 is an error (or at least it doesn't do what you might expect). Later we'll talk about compiling
1176 and immediate mode, and you'll understand why.
1177 */
1179 defcode "WORD",4,,WORD
1180 call _WORD
1181 push %ecx // push length
1182 push %edi // push base address
1183 NEXT
1185 _WORD:
1186 /* Search for first non-blank character. Also skip \ comments. */
1187 1:
1188 call _KEY // get next key, returned in %eax
1189 cmpb $'\\',%al // start of a comment?
1190 je 3f // if so, skip the comment
1191 cmpb $' ',%al
1192 jbe 1b // if so, keep looking
1194 /* Search for the end of the word, storing chars as we go. */
1195 mov $5f,%edi // pointer to return buffer
1196 2:
1197 stosb // add character to return buffer
1198 call _KEY // get next key, returned in %al
1199 cmpb $' ',%al // is blank?
1200 ja 2b // if not, keep looping
1202 /* Return the word (well, the static buffer) and length. */
1203 sub $5f,%edi
1204 mov %edi,%ecx // return length of the word
1205 mov $5f,%edi // return address of the word
1206 ret
1208 /* Code to skip \ comments to end of the current line. */
1209 3:
1210 call _KEY
1211 cmpb $'\n',%al // end of line yet?
1212 jne 3b
1213 jmp 1b
1215 .bss
1216 // A static buffer where WORD returns. Subsequent calls
1217 // overwrite this buffer. Maximum word length is 32 chars.
1218 5: .space 32
1220 /*
1221 . (also called DOT) prints the top of the stack as an integer. In real FORTH implementations
1222 it should print it in the current base, but this assembler version is simpler and can only
1223 print in base 10.
1225 Remember that you can override even built-in FORTH words easily, so if you want to write a
1226 more advanced DOT then you can do so easily at a later point, and probably in FORTH.
1227 */
1229 defcode ".",1,,DOT
1230 pop %eax // Get the number to print into %eax
1231 call _DOT // Easier to do this recursively ...
1232 NEXT
1233 _DOT:
1234 mov $10,%ecx // Base 10
1235 1:
1236 cmp %ecx,%eax
1237 jb 2f
1238 xor %edx,%edx // %edx:%eax / %ecx -> quotient %eax, remainder %edx
1239 idivl %ecx
1240 pushl %edx
1241 call _DOT
1242 popl %eax
1243 jmp 1b
1244 2:
1245 xor %ah,%ah
1246 aam $10
1247 cwde
1248 addl $'0',%eax
1249 call _EMIT
1250 ret
1252 /*
1253 Almost the opposite of DOT (but not quite), SNUMBER parses a numeric string such as one returned
1254 by WORD and pushes the number on the parameter stack.
1256 This function does absolutely no error checking, and in particular the length of the string
1257 must be >= 1 bytes, and should contain only digits 0-9. If it doesn't you'll get random results.
1259 This function is only used when reading literal numbers in code, and shouldn't really be used
1260 in user code at all.
1261 */
1262 defcode "SNUMBER",7,,SNUMBER
1263 pop %edi
1264 pop %ecx
1265 call _SNUMBER
1266 push %eax
1267 NEXT
1268 _SNUMBER:
1269 xor %eax,%eax
1270 xor %ebx,%ebx
1271 1:
1272 imull $10,%eax // %eax *= 10
1273 movb (%edi),%bl
1274 inc %edi
1275 subb $'0',%bl // ASCII -> digit
1276 add %ebx,%eax
1277 dec %ecx
1278 jnz 1b
1279 ret
1281 /*
1282 DICTIONARY LOOK UPS ----------------------------------------------------------------------
1284 We're building up to our prelude on how FORTH code is compiled, but first we need yet more infrastructure.
1286 The FORTH word FIND takes a string (a word as parsed by WORD -- see above) and looks it up in the
1287 dictionary. What it actually returns is the address of the dictionary header, if it finds it,
1288 or 0 if it didn't.
1290 So if DOUBLE is defined in the dictionary, then WORD DOUBLE FIND returns the following pointer:
1292 pointer to this
1293 |
1294 |
1295 V
1296 +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1297 | LINK | 6 | D | O | U | B | L | E | 0 | DOCOL | DUP | + | EXIT |
1298 +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1300 See also >CFA which takes a dictionary entry pointer and returns a pointer to the codeword.
1302 FIND doesn't find dictionary entries which are flagged as HIDDEN. See below for why.
1303 */
1305 defcode "FIND",4,,FIND
1306 pop %edi // %edi = address
1307 pop %ecx // %ecx = length
1308 call _FIND
1309 push %eax
1310 NEXT
1312 _FIND:
1313 push %esi // Save %esi so we can use it in string comparison.
1315 // Now we start searching backwards through the dictionary for this word.
1316 mov var_LATEST,%edx // LATEST points to name header of the latest word in the dictionary
1317 1:
1318 test %edx,%edx // NULL pointer? (end of the linked list)
1319 je 4f
1321 // Compare the length expected and the length of the word.
1322 // Note that if the F_HIDDEN flag is set on the word, then by a bit of trickery
1323 // this won't pick the word (the length will appear to be wrong).
1324 xor %eax,%eax
1325 movb 4(%edx),%al // %al = flags+length field
1326 andb $(F_HIDDEN|0x1f),%al // %al = name length
1327 cmpb %cl,%al // Length is the same?
1328 jne 2f
1330 // Compare the strings in detail.
1331 push %ecx // Save the length
1332 push %edi // Save the address (repe cmpsb will move this pointer)
1333 lea 5(%edx),%esi // Dictionary string we are checking against.
1334 repe cmpsb // Compare the strings.
1335 pop %edi
1336 pop %ecx
1337 jne 2f // Not the same.
1339 // The strings are the same - return the header pointer in %eax
1340 pop %esi
1341 mov %edx,%eax
1342 ret
1344 2:
1345 mov (%edx),%edx // Move back through the link field to the previous word
1346 jmp 1b // .. and loop.
1348 4: // Not found.
1349 pop %esi
1350 xor %eax,%eax // Return zero to indicate not found.
1351 ret
1353 /*
1354 FIND returns the dictionary pointer, but when compiling we need the codeword pointer (recall
1355 that FORTH definitions are compiled into lists of codeword pointers). The standard FORTH
1356 word >CFA turns a dictionary pointer into a codeword pointer.
1358 The example below shows the result of:
1360 WORD DOUBLE FIND >CFA
1362 FIND returns a pointer to this
1363 | >CFA converts it to a pointer to this
1364 | |
1365 V V
1366 +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1367 | LINK | 6 | D | O | U | B | L | E | 0 | DOCOL | DUP | + | EXIT |
1368 +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1370 Notes:
1372 Because names vary in length, this isn't just a simple increment.
1374 In this FORTH you cannot easily turn a codeword pointer back into a dictionary entry pointer, but
1375 that is not true in most FORTH implementations where they store a back pointer in the definition
1376 (with an obvious memory/complexity cost). The reason they do this is that it is useful to be
1377 able to go backwards (codeword -> dictionary entry) in order to decompile FORTH definitions.
1379 What does CFA stand for? My best guess is "Code Field Address".
1380 */
1382 defcode ">CFA",4,,TCFA
1383 pop %edi
1384 call _TCFA
1385 push %edi
1386 NEXT
1387 _TCFA:
1388 xor %eax,%eax
1389 add $4,%edi // Skip link pointer.
1390 movb (%edi),%al // Load flags+len into %al.
1391 inc %edi // Skip flags+len byte.
1392 andb $0x1f,%al // Just the length, not the flags.
1393 add %eax,%edi // Skip the name.
1394 addl $3,%edi // The codeword is 4-byte aligned.
1395 andl $~3,%edi
1396 ret
1398 /*
1399 COMPILING ----------------------------------------------------------------------
1401 Now we'll talk about how FORTH compiles words. Recall that a word definition looks like this:
1403 : DOUBLE DUP + ;
1405 and we have to turn this into:
1407 pointer to previous word
1408 ^
1409 |
1410 +--|------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1411 | LINK | 6 | D | O | U | B | L | E | 0 | DOCOL | DUP | + | EXIT |
1412 +---------+---+---+---+---+---+---+---+---+------------+--|---------+------------+------------+
1413 ^ len pad codeword |
1414 | V
1415 LATEST points here points to codeword of DUP
1417 There are several problems to solve. Where to put the new word? How do we read words? How
1418 do we define the words : (COLON) and ; (SEMICOLON)?
1420 FORTH solves this rather elegantly and as you might expect in a very low-level way which
1421 allows you to change how the compiler works on your own code.
1423 FORTH has an INTERPRETER function (a true interpreter this time, not DOCOL) which runs in a
1424 loop, reading words (using WORD), looking them up (using FIND), turning them into codeword
1425 pointers (using >CFA) and deciding what to do with them.
1427 What it does depends on the mode of the interpreter (in variable STATE).
1429 When STATE is zero, the interpreter just runs each word as it looks them up. This is known as
1430 immediate mode.
1432 The interesting stuff happens when STATE is non-zero -- compiling mode. In this mode the
1433 interpreter appends the codeword pointer to user memory (the HERE variable points to the next
1434 free byte of user memory).
1436 So you may be able to see how we could define : (COLON). The general plan is:
1438 (1) Use WORD to read the name of the function being defined.
1440 (2) Construct the dictionary entry -- just the header part -- in user memory:
1442 pointer to previous word (from LATEST) +-- Afterwards, HERE points here, where
1443 ^ | the interpreter will start appending
1444 | V codewords.
1445 +--|------+---+---+---+---+---+---+---+---+------------+
1446 | LINK | 6 | D | O | U | B | L | E | 0 | DOCOL |
1447 +---------+---+---+---+---+---+---+---+---+------------+
1448 len pad codeword
1450 (3) Set LATEST to point to the newly defined word, ...
1452 (4) .. and most importantly leave HERE pointing just after the new codeword. This is where
1453 the interpreter will append codewords.
1455 (5) Set STATE to 1. This goes into compile mode so the interpreter starts appending codewords to
1456 our partially-formed header.
1458 After : has run, our input is here:
1460 : DOUBLE DUP + ;
1461 ^
1462 |
1463 Next byte returned by KEY
1465 so the interpreter (now it's in compile mode, so I guess it's really the compiler) reads DUP,
1466 gets its codeword pointer, and appends it:
1468 +-- HERE updated to point here.
1469 |
1470 V
1471 +---------+---+---+---+---+---+---+---+---+------------+------------+
1472 | LINK | 6 | D | O | U | B | L | E | 0 | DOCOL | DUP |
1473 +---------+---+---+---+---+---+---+---+---+------------+------------+
1474 len pad codeword
1476 Next we read +, get the codeword pointer, and append it:
1478 +-- HERE updated to point here.
1479 |
1480 V
1481 +---------+---+---+---+---+---+---+---+---+------------+------------+------------+
1482 | LINK | 6 | D | O | U | B | L | E | 0 | DOCOL | DUP | + |
1483 +---------+---+---+---+---+---+---+---+---+------------+------------+------------+
1484 len pad codeword
1486 The issue is what happens next. Obviously what we _don't_ want to happen is that we
1487 read ";" and compile it and go on compiling everything afterwards.
1489 At this point, FORTH uses a trick. Remember the length byte in the dictionary definition
1490 isn't just a plain length byte, but can also contain flags. One flag is called the
1491 IMMEDIATE flag (F_IMMED in this code). If a word in the dictionary is flagged as
1492 IMMEDIATE then the interpreter runs it immediately _even if it's in compile mode_.
1494 I hope I don't need to explain that ; (SEMICOLON) just such a word, flagged as IMMEDIATE.
1495 And all it does is append the codeword for EXIT on to the current definition and switch
1496 back to immediate mode (set STATE back to 0). Shortly we'll see the actual definition
1497 of ; and we'll see that it's really a very simple definition, declared IMMEDIATE.
1499 After the interpreter reads ; and executes it 'immediately', we get this:
1501 +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1502 | LINK | 6 | D | O | U | B | L | E | 0 | DOCOL | DUP | + | EXIT |
1503 +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1504 len pad codeword ^
1505 |
1506 HERE
1508 STATE is set to 0.
1510 And that's it, job done, our new definition is compiled, and we're back in immediate mode
1511 just reading and executing words, perhaps including a call to test our new word DOUBLE.
1513 The only last wrinkle in this is that while our word was being compiled, it was in a
1514 half-finished state. We certainly wouldn't want DOUBLE to be called somehow during
1515 this time. There are several ways to stop this from happening, but in FORTH what we
1516 do is flag the word with the HIDDEN flag (F_HIDDEN in this code) just while it is
1517 being compiled. This prevents FIND from finding it, and thus in theory stops any
1518 chance of it being called.
1520 Compared to the description above, the actual definition of : (COLON) is comparatively simple:
1521 */
1523 defcode ":",1,,COLON
1525 // Get the word and create a dictionary entry header for it.
1526 call _WORD // Returns %ecx = length, %edi = pointer to word.
1527 mov %edi,%ebx // %ebx = address of the word
1529 movl var_HERE,%edi // %edi is the address of the header
1530 movl var_LATEST,%eax // Get link pointer
1531 stosl // and store it in the header.
1533 mov %cl,%al // Get the length.
1534 orb $F_HIDDEN,%al // Set the HIDDEN flag on this entry.
1535 stosb // Store the length/flags byte.
1536 push %esi
1537 mov %ebx,%esi // %esi = word
1538 rep movsb // Copy the word
1539 pop %esi
1540 addl $3,%edi // Align to next 4 byte boundary.
1541 andl $~3,%edi
1543 movl $DOCOL,%eax // The codeword for user-created words is always DOCOL (the interpreter)
1544 stosl
1546 // Header built, so now update LATEST and HERE.
1547 // We'll be compiling words and putting them HERE.
1548 movl var_HERE,%eax
1549 movl %eax,var_LATEST
1550 movl %edi,var_HERE
1552 // And go into compile mode by setting STATE to 1.
1553 movl $1,var_STATE
1554 NEXT
1556 /*
1557 , (COMMA) is a standard FORTH word which appends a 32 bit integer (normally a codeword
1558 pointer) to the user data area pointed to by HERE, and adds 4 to HERE.
1559 */
1561 defcode ",",1,,COMMA
1562 pop %eax // Code pointer to store.
1563 call _COMMA
1564 NEXT
1565 _COMMA:
1566 movl var_HERE,%edi // HERE
1567 stosl // Store it.
1568 movl %edi,var_HERE // Update HERE (incremented)
1569 ret
1571 /*
1572 ; (SEMICOLON) is also elegantly simple. Notice the F_IMMED flag.
1573 */
1575 defcode ";",1,F_IMMED,SEMICOLON
1576 movl $EXIT,%eax // EXIT is the final codeword in compiled words.
1577 call _COMMA // Store it.
1578 call _HIDDEN // Toggle the HIDDEN flag (unhides the new word).
1579 xor %eax,%eax // Set STATE to 0 (back to execute mode).
1580 movl %eax,var_STATE
1581 NEXT
1583 /*
1584 EXTENDING THE COMPILER ----------------------------------------------------------------------
1586 Words flagged with IMMEDIATE (F_IMMED) aren't just for the FORTH compiler to use. You can define
1587 your own IMMEDIATE words too, and this is a crucial aspect when extending basic FORTH, because
1588 it allows you in effect to extend the compiler itself. Does gcc let you do that?
1590 Standard FORTH words like IF, WHILE, .", [ and so on are all written as extensions to the basic
1591 compiler, and are all IMMEDIATE words.
1593 The IMMEDIATE word toggles the F_IMMED (IMMEDIATE flag) on the most recently defined word,
1594 or on the current word if you call it in the middle of a definition.
1596 Typical usage is:
1598 : MYIMMEDWORD IMMEDIATE
1599 ...definition...
1600 ;
1602 but some FORTH programmers write this instead:
1604 : MYIMMEDWORD
1605 ...definition...
1606 ; IMMEDIATE
1608 The two usages are equivalent, to a first approximation.
1609 */
1611 defcode "IMMEDIATE",9,F_IMMED,IMMEDIATE
1612 call _IMMEDIATE
1613 NEXT
1614 _IMMEDIATE:
1615 movl var_LATEST,%edi // LATEST word.
1616 addl $4,%edi // Point to name/flags byte.
1617 xorb $F_IMMED,(%edi) // Toggle the IMMED bit.
1618 ret
1620 /*
1621 HIDDEN toggles the other flag, F_HIDDEN, of the latest word. Note that words flagged
1622 as hidden are defined but cannot be called, so this is rarely used.
1623 */
1625 defcode "HIDDEN",6,,HIDDEN
1626 call _HIDDEN
1627 NEXT
1628 _HIDDEN:
1629 movl var_LATEST,%edi // LATEST word.
1630 addl $4,%edi // Point to name/flags byte.
1631 xorb $F_HIDDEN,(%edi) // Toggle the HIDDEN bit.
1632 ret
1634 /*
1635 ' (TICK) is a standard FORTH word which returns the codeword pointer of the next word.
1637 The common usage is:
1639 ' FOO ,
1641 which appends the codeword of FOO to the current word we are defining (this only works in compiled code).
1643 You tend to use ' in IMMEDIATE words. For example an alternate (and rather useless) way to define
1644 a literal 2 might be:
1646 : LIT2 IMMEDIATE
1647 ' LIT , \ Appends LIT to the currently-being-defined word
1648 2 , \ Appends the number 2 to the currently-being-defined word
1649 ;
1651 So you could do:
1653 : DOUBLE LIT2 * ;
1655 (If you don't understand how LIT2 works, then you should review the material about compiling words
1656 and immediate mode).
1658 This definition of ' uses a cheat which I copied from buzzard92. As a result it only works in
1659 compiled code. It is possible to write a version of ' based on WORD, FIND, >CFA which works in
1660 immediate mode too.
1661 */
1662 defcode "'",1,,TICK
1663 lodsl // Get the address of the next word and skip it.
1664 pushl %eax // Push it on the stack.
1665 NEXT
1667 /*
1668 BRANCHING ----------------------------------------------------------------------
1670 It turns out that all you need in order to define looping constructs, IF-statements, etc.
1671 are two primitives.
1673 BRANCH is an unconditional branch. 0BRANCH is a conditional branch (it only branches if the
1674 top of stack is zero).
1676 The diagra below shows how BRANCH works in some imaginary compiled word. When BRANCH executes,
1677 %esi starts by pointing to the offset field (compare to LIT above):
1679 +---------------------+-------+---- - - ---+------------+------------+---- - - - ----+------------+
1680 | (Dictionary header) | DOCOL | | BRANCH | offset | (skipped) | word |
1681 +---------------------+-------+---- - - ---+------------+-----|------+---- - - - ----+------------+
1682 ^ | ^
1683 | | |
1684 | +-----------------------+
1685 %esi added to offset
1687 The offset is added to %esi to make the new %esi, and the result is that when NEXT runs, execution
1688 continues at the branch target. Negative offsets work as expected.
1690 0BRANCH is the same except the branch happens conditionally.
1692 Now standard FORTH words such as IF, THEN, ELSE, WHILE, REPEAT, etc. can be implemented entirely
1693 in FORTH. They are IMMEDIATE words which append various combinations of BRANCH or 0BRANCH
1694 into the word currently being compiled.
1696 As an example, code written like this:
1698 condition-code IF true-part THEN rest-code
1700 compiles to:
1702 condition-code 0BRANCH OFFSET true-part rest-code
1703 | ^
1704 | |
1705 +-------------+
1706 */
1708 defcode "BRANCH",6,,BRANCH
1709 add (%esi),%esi // add the offset to the instruction pointer
1710 NEXT
1712 defcode "0BRANCH",7,,ZBRANCH
1713 pop %eax
1714 test %eax,%eax // top of stack is zero?
1715 jz code_BRANCH // if so, jump back to the branch function above
1716 lodsl // otherwise we need to skip the offset
1717 NEXT
1719 /*
1720 PRINTING STRINGS ----------------------------------------------------------------------
1722 LITSTRING and EMITSTRING are primitives used to implement the ." operator (which is
1723 written in FORTH). See the definition of that operator below.
1724 */
1726 defcode "LITSTRING",9,,LITSTRING
1727 lodsl // get the length of the string
1728 push %eax // push it on the stack
1729 push %esi // push the address of the start of the string
1730 addl %eax,%esi // skip past the string
1731 addl $3,%esi // but round up to next 4 byte boundary
1732 andl $~3,%esi
1733 NEXT
1735 defcode "EMITSTRING",10,,EMITSTRING
1736 mov $1,%ebx // 1st param: stdout
1737 pop %ecx // 2nd param: address of string
1738 pop %edx // 3rd param: length of string
1739 mov $__NR_write,%eax // write syscall
1740 int $0x80
1741 NEXT
1743 /*
1744 COLD START AND INTERPRETER ----------------------------------------------------------------------
1746 COLD is the first FORTH function called, almost immediately after the FORTH system "boots".
1748 INTERPRETER is the FORTH interpreter ("toploop", "toplevel" or "REPL" might be a more accurate
1749 description -- see: http://en.wikipedia.org/wiki/REPL).
1750 */
1753 // COLD must not return (ie. must not call EXIT).
1754 defword "COLD",4,,COLD
1755 .int INTERPRETER // call the interpreter loop (never returns)
1756 .int LIT,1,SYSEXIT // hmmm, but in case it does, exit(1).
1758 /* This interpreter is pretty simple, but remember that in FORTH you can always override
1759 * it later with a more powerful one!
1760 */
1761 defword "INTERPRETER",11,,INTERPRETER
1762 .int INTERPRET,RDROP,INTERPRETER
1764 defcode "INTERPRET",9,,INTERPRET
1765 call _WORD // Returns %ecx = length, %edi = pointer to word.
1767 // Is it in the dictionary?
1768 xor %eax,%eax
1769 movl %eax,interpret_is_lit // Not a literal number (not yet anyway ...)
1770 call _FIND // Returns %eax = pointer to header or 0 if not found.
1771 test %eax,%eax // Found?
1772 jz 1f
1774 // In the dictionary. Is it an IMMEDIATE codeword?
1775 mov %eax,%edi // %edi = dictionary entry
1776 movb 4(%edi),%al // Get name+flags.
1777 push %ax // Just save it for now.
1778 call _TCFA // Convert dictionary entry (in %edi) to codeword pointer.
1779 pop %ax
1780 andb $F_IMMED,%al // Is IMMED flag set?
1781 mov %edi,%eax
1782 jnz 4f // If IMMED, jump straight to executing.
1784 jmp 2f
1786 1: // Not in the dictionary (not a word) so assume it's a literal number.
1787 incl interpret_is_lit
1788 call _SNUMBER // Returns the parsed number in %eax
1789 mov %eax,%ebx
1790 mov $LIT,%eax // The word is LIT
1792 2: // Are we compiling or executing?
1793 movl var_STATE,%edx
1794 test %edx,%edx
1795 jz 4f // Jump if executing.
1797 // Compiling - just append the word to the current dictionary definition.
1798 call _COMMA
1799 mov interpret_is_lit,%ecx // Was it a literal?
1800 test %ecx,%ecx
1801 jz 3f
1802 mov %ebx,%eax // Yes, so LIT is followed by a number.
1803 call _COMMA
1804 3: NEXT
1806 4: // Executing - run it!
1807 mov interpret_is_lit,%ecx // Literal?
1808 test %ecx,%ecx // Literal?
1809 jnz 5f
1811 // Not a literal, execute it now. This never returns, but the codeword will
1812 // eventually call NEXT which will reenter the loop in INTERPRETER.
1813 jmp *(%eax)
1815 5: // Executing a literal, which means push it on the stack.
1816 push %ebx
1817 NEXT
1819 .data
1820 .align 4
1821 interpret_is_lit:
1822 .int 0 // Flag used to record if reading a literal
1824 /*
1825 ODDS AND ENDS ----------------------------------------------------------------------
1827 CHAR puts the ASCII code of the first character of the following word on the stack. For example
1828 CHAR A puts 65 on the stack.
1830 SYSEXIT exits the process using Linux exit syscall.
1831 */
1833 defcode "CHAR",4,,CHAR
1834 call _WORD // Returns %ecx = length, %edi = pointer to word.
1835 xor %eax,%eax
1836 movb (%edi),%al // Get the first character of the word.
1837 push %eax // Push it onto the stack.
1838 NEXT
1840 // NB: SYSEXIT must be the last entry in the built-in dictionary.
1841 defcode SYSEXIT,7,,SYSEXIT
1842 pop %ebx
1843 mov $__NR_exit,%eax
1844 int $0x80
1846 /*
1847 START OF FORTH CODE ----------------------------------------------------------------------
1849 We've now reached the stage where the FORTH system is running and self-hosting. All further
1850 words can be written as FORTH itself, including words like IF, THEN, .", etc which in most
1851 languages would be considered rather fundamental.
1853 As a kind of trick, I prefill the input buffer with the initial FORTH code. Once this code
1854 has run (when we get to the "OK" prompt), this input buffer is reused for reading any further
1855 user input.
1857 Some notes about the code:
1859 \ (backslash) is the FORTH way to start a comment which goes up to the next newline. However
1860 because this is a C-style string, I have to escape the backslash, which is why they appear as
1861 \\ comment.
1863 Similarly, any backslashes in the code are doubled, and " becomes \" (eg. the definition of ."
1864 is written as : .\" ... ;)
1866 I use indenting to show structure. The amount of whitespace has no meaning to FORTH however
1867 except that you must use at least one whitespace character between words, and words themselves
1868 cannot contain whitespace.
1870 FORTH is case-sensitive. Use capslock!
1872 Enjoy!
1873 */
1875 .data
1876 .align 4096
1877 buffer:
1878 // Multi-line constant gives 'Warning: unterminated string; newline inserted' messages which you can ignore.
1879 .ascii "\
1880 \\ Define some character constants
1881 : '\\n' 10 ;
1882 : 'SPACE' 32 ;
1883 : '\"' 34 ;
1884 : ':' 58 ;
1886 \\ CR prints a carriage return
1887 : CR '\\n' EMIT ;
1889 \\ SPACE prints a space
1890 : SPACE 'SPACE' EMIT ;
1892 \\ Primitive . (DOT) function doesn't follow with a blank, so redefine it to behave like FORTH.
1893 \\ Notice how we can trivially redefine existing functions.
1894 : . . SPACE ;
1896 \\ DUP, DROP are defined in assembly for speed, but this is how you might define them
1897 \\ in FORTH. Notice use of the scratch variables _X and _Y.
1898 \\ : DUP _X ! _X @ _X @ ;
1899 \\ : DROP _X ! ;
1901 \\ The 2... versions of the standard operators work on pairs of stack entries. They're not used
1902 \\ very commonly so not really worth writing in assembler. Here is how they are defined in FORTH.
1903 : 2DUP OVER OVER ;
1904 : 2DROP DROP DROP ;
1906 \\ More standard FORTH words.
1907 : 2* 2 * ;
1908 : 2/ 2 / ;
1910 \\ [ and ] allow you to break into immediate mode while compiling a word.
1911 : [ IMMEDIATE \\ define [ as an immediate word
1912 0 STATE ! \\ go into immediate mode
1913 ;
1915 : ]
1916 1 STATE ! \\ go back to compile mode
1917 ;
1919 \\ LITERAL takes whatever is on the stack and compiles LIT <foo>
1920 : LITERAL IMMEDIATE
1921 ' LIT , \\ compile LIT
1922 , \\ compile the literal itself (from the stack)
1923 ;
1925 \\ condition IF true-part THEN rest
1926 \\ compiles to:
1927 \\ condition 0BRANCH OFFSET true-part rest
1928 \\ where OFFSET is the offset of 'rest'
1929 \\ condition IF true-part ELSE false-part THEN
1930 \\ compiles to:
1931 \\ condition 0BRANCH OFFSET true-part BRANCH OFFSET2 false-part rest
1932 \\ where OFFSET if the offset of false-part and OFFSET2 is the offset of rest
1934 \\ IF is an IMMEDIATE word which compiles 0BRANCH followed by a dummy offset, and places
1935 \\ the address of the 0BRANCH on the stack. Later when we see THEN, we pop that address
1936 \\ off the stack, calculate the offset, and back-fill the offset.
1937 : IF IMMEDIATE
1938 ' 0BRANCH , \\ compile 0BRANCH
1939 HERE @ \\ save location of the offset on the stack
1940 0 , \\ compile a dummy offset
1941 ;
1943 : THEN IMMEDIATE
1944 DUP
1945 HERE @ SWAP - \\ calculate the offset from the address saved on the stack
1946 SWAP ! \\ store the offset in the back-filled location
1947 ;
1949 : ELSE IMMEDIATE
1950 ' BRANCH , \\ definite branch to just over the false-part
1951 HERE @ \\ save location of the offset on the stack
1952 0 , \\ compile a dummy offset
1953 SWAP \\ now back-fill the original (IF) offset
1954 DUP \\ same as for THEN word above
1955 HERE @ SWAP -
1956 SWAP !
1957 ;
1959 \\ BEGIN loop-part condition UNTIL
1960 \\ compiles to:
1961 \\ loop-part condition 0BRANCH OFFSET
1962 \\ where OFFSET points back to the loop-part
1963 \\ This is like do { loop-part } while (condition) in the C language
1964 : BEGIN IMMEDIATE
1965 HERE @ \\ save location on the stack
1966 ;
1968 : UNTIL IMMEDIATE
1969 ' 0BRANCH , \\ compile 0BRANCH
1970 HERE @ - \\ calculate the offset from the address saved on the stack
1971 , \\ compile the offset here
1972 ;
1974 \\ BEGIN loop-part AGAIN
1975 \\ compiles to:
1976 \\ loop-part BRANCH OFFSET
1977 \\ where OFFSET points back to the loop-part
1978 \\ In other words, an infinite loop which can only be returned from with EXIT
1979 : AGAIN IMMEDIATE
1980 ' BRANCH , \\ compile BRANCH
1981 HERE @ - \\ calculate the offset back
1982 , \\ compile the offset here
1983 ;
1985 \\ BEGIN condition WHILE loop-part REPEAT
1986 \\ compiles to:
1987 \\ condition 0BRANCH OFFSET2 loop-part BRANCH OFFSET
1988 \\ where OFFSET points back to condition (the beginning) and OFFSET2 points to after the whole piece of code
1989 \\ So this is like a while (condition) { loop-part } loop in the C language
1990 : WHILE IMMEDIATE
1991 ' 0BRANCH , \\ compile 0BRANCH
1992 HERE @ \\ save location of the offset2 on the stack
1993 0 , \\ compile a dummy offset2
1994 ;
1996 : REPEAT IMMEDIATE
1997 ' BRANCH , \\ compile BRANCH
1998 SWAP \\ get the original offset (from BEGIN)
1999 HERE @ - , \\ and compile it after BRANCH
2000 DUP
2001 HERE @ SWAP - \\ calculate the offset2
2002 SWAP ! \\ and back-fill it in the original location
2003 ;
2005 \\ With the looping constructs, we can now write SPACES, which writes n spaces to stdout.
2006 : SPACES
2007 BEGIN
2008 SPACE \\ print a space
2009 1- \\ until we count down to 0
2010 DUP 0=
2011 UNTIL
2012 ;
2014 \\ .S prints the contents of the stack. Very useful for debugging.
2015 : .S
2016 DSP@ \\ get current stack pointer
2017 BEGIN
2018 DUP @ . \\ print the stack element
2019 4+ \\ move up
2020 DUP S0 @ 4- = \\ stop when we get to the top
2021 UNTIL
2022 DROP
2023 ;
2025 \\ DEPTH returns the depth of the stack.
2026 : DEPTH S0 @ DSP@ - ;
2028 \\ .\" is the print string operator in FORTH. Example: .\" Something to print\"
2029 \\ The space after the operator is the ordinary space required between words.
2030 \\ This is tricky to define because it has to do different things depending on whether
2031 \\ we are compiling or in immediate mode. (Thus the word is marked IMMEDIATE so it can
2032 \\ detect this and do different things).
2033 \\ In immediate mode we just keep reading characters and printing them until we get to
2034 \\ the next double quote.
2035 \\ In compile mode we have the problem of where we're going to store the string (remember
2036 \\ that the input buffer where the string comes from may be overwritten by the time we
2037 \\ come round to running the function). We store the string in the compiled function
2038 \\ like this:
2039 \\ ..., LITSTRING, string length, string rounded up to 4 bytes, EMITSTRING, ...
2040 : .\" IMMEDIATE
2041 STATE @ \\ compiling?
2042 IF
2043 ' LITSTRING , \\ compile LITSTRING
2044 HERE @ \\ save the address of the length word on the stack
2045 0 , \\ dummy length - we don't know what it is yet
2046 BEGIN
2047 KEY \\ get next character of the string
2048 DUP '\"' <>
2049 WHILE
2050 HERE @ !b \\ store the character in the compiled image
2051 1 HERE +! \\ increment HERE pointer by 1 byte
2052 REPEAT
2053 DROP \\ drop the double quote character at the end
2054 DUP \\ get the saved address of the length word
2055 HERE @ SWAP - \\ calculate the length
2056 4- \\ subtract 4 (because we measured from the start of the length word)
2057 SWAP ! \\ and back-fill the length location
2058 HERE @ \\ round up to next multiple of 4 bytes for the remaining code
2059 3 +
2060 3 INVERT AND
2061 HERE !
2062 ' EMITSTRING , \\ compile the final EMITSTRING
2063 ELSE
2064 \\ In immediate mode, just read characters and print them until we get
2065 \\ to the ending double quote. Much simpler than the above code!
2066 BEGIN
2067 KEY
2068 DUP '\"' = IF EXIT THEN
2069 EMIT
2070 AGAIN
2071 THEN
2072 ;
2074 \\ While compiling, [COMPILE] WORD compiles WORD if it would otherwise be IMMEDIATE.
2075 : [COMPILE] IMMEDIATE
2076 WORD \\ get the next word
2077 FIND \\ find it in the dictionary
2078 >CFA \\ get its codeword
2079 , \\ and compile that
2080 ;
2082 \\ RECURSE makes a recursive call to the current word that is being compiled.
2083 \\ Normally while a word is being compiled, it is marked HIDDEN so that references to the
2084 \\ same word within are calls to the previous definition of the word.
2085 : RECURSE IMMEDIATE
2086 LATEST @ >CFA \\ LATEST points to the word being compiled at the moment
2087 , \\ compile it
2088 ;
2090 \\ ALLOT is used to allocate (static) memory when compiling. It increases HERE by
2091 \\ the amount given on the stack.
2092 \\: ALLOT HERE +! ;
2095 \\ Finally print the welcome prompt.
2096 .\" JONESFORTH VERSION \" VERSION @ . CR
2097 .\" OK \"
2098 "
2100 _initbufftop:
2101 .align 4096
2102 buffend:
2104 currkey:
2105 .int buffer
2106 bufftop:
2107 .int _initbufftop
2109 /* END OF jonesforth.S */